////////////////////////////////
////FOOTBALL MASSACRE SCRIPT////
////////////////////////////////

PLAYER_PED p1 = ( 136.5 , 105.5 , 3.0 ) 25 270 

OBJ_DATA football = ( 140.5 , 102.5 , 2.0 ) 0 FOOTY
OBJ_DATA generator1 = ( 94.5 , 104.5 , 2.0 ) 0 POWERGEN
OBJ_DATA generator2 = ( 86.5 , 88.5 , 2.0 ) 0 POWERGEN

// Arrows
ARROW_DATA arrow01
ARROW_DATA arrow_end

// Sounds
SOUND generator_rumble1
SOUND generator_rumble2
SOUND door_opening
SOUND generator_lose_power
SOUND football_crowd = ( 140.5 , 102.5 , 3.0 ) PRISON_YARD PLAY_FOREVER

// Cars
CAR_DATA srs_bus
CAR_DATA finish_van
PARKED_CAR_DATA srs01 = ( 140.5 , 91.5 , 2.0 ) 10 180 VAN
PARKED_CAR_DATA srs02 = ( 139.5 , 92.5 , 2.0 ) 10 45 STRATOS
PARKED_CAR_DATA srs03 = ( 141.5 , 92.5 , 2.0 ) 10 315 STRATOS

// Characters
	// Football Players
		// Besaid Aurochs
CHAR_DATA besaid_keeper = ( 136.5 , 102.5 , 2.0 ) 32 90 DUMMY
CHAR_DATA besaid01 = ( 139.6 , 102.5 , 2.0 ) 32 90 DUMMY
CHAR_DATA besaid02 = ( 138.6 , 101.5 , 2.0 ) 32 90 DUMMY
CHAR_DATA besaid03 = ( 138.6 , 102.5 , 2.0 ) 32 90 DUMMY
CHAR_DATA besaid04 = ( 138.6 , 103.5 , 2.0 ) 32 90 DUMMY
		// Kilika Beasts
CHAR_DATA kilika_keeper = ( 144.5 , 102.5 , 2.0 ) 31 270 DUMMY
CHAR_DATA kilika01 = ( 141.5 , 102.5 , 2.0 ) 31 270 DUMMY
CHAR_DATA kilika02 = ( 142.5 , 101.5 , 2.0 ) 31 270 DUMMY
CHAR_DATA kilika03 = ( 142.5 , 102.5 , 2.0 ) 31 270 DUMMY
CHAR_DATA kilika04 = ( 142.5 , 103.5 , 2.0 ) 31 270 DUMMY
	// Dead Guards in Stadium
CHAR_DATA guard01 = ( 137.5 , 95.5 , 2.0 ) 13 270 DUMMY
CHAR_DATA guard02 = ( 143.5 , 95.5 , 2.0 ) 13 270 DUMMY
CHAR_DATA guard03 = ( 139.5 , 93.5 , 2.0 ) 13 180 DUMMY
	// SRS Attackers
CHAR_DATA srs_pk01 = ( 136.5 , 95.5 , 2.0 ) 7 90 CRIMINAL_TYPE2
CHAR_DATA srs_pk02 = ( 135.5 , 95.5 , 2.0 ) 7 90 CRIMINAL_TYPE2
CHAR_DATA srs_pk03 = ( 144.5 , 95.5 , 2.0 ) 7 270 CRIMINAL_TYPE2
CHAR_DATA srs_pk04 = ( 145.5 , 95.5 , 2.0 ) 7 270 CRIMINAL_TYPE2
	// SRS Prison Shooters
CHAR_DATA srs_shoot01 = ( 70.5 , 120.5 , 2.0 ) 7 180 CRIMINAL_TYPE2
CHAR_DATA srs_shoot02 = ( 71.5 , 120.5 , 2.0 ) 7 180 CRIMINAL_TYPE2
CHAR_DATA srs_shoot03 = ( 72.5 , 120.5 , 2.0 ) 7 180 CRIMINAL_TYPE2
CHAR_DATA srs_shoot04 = ( 77.5 , 120.5 , 2.0 ) 7 180 CRIMINAL_TYPE2
CHAR_DATA srs_shoot05 = ( 78.5 , 120.5 , 2.0 ) 7 180 CRIMINAL_TYPE2
CHAR_DATA srs_shoot06 = ( 79.5 , 120.5 , 2.0 ) 7 180 CRIMINAL_TYPE2
	// SRS Attackers when generator 1 destroyed
CHAR_DATA srs_gen1_01
CHAR_DATA srs_gen1_02
CHAR_DATA srs_gen1_03
CHAR_DATA srs_gen1_04
CHAR_DATA srs_gen1_05
CHAR_DATA srs_gen1_06
	// Captured people
CHAR_DATA prisoner01
CHAR_DATA prisoner02
CHAR_DATA prisoner03
CHAR_DATA prisoner04
CHAR_DATA prisoner05
CHAR_DATA prisoner06
CHAR_DATA prisoner07
CHAR_DATA prisoner08

// Generators
GENERATOR crusher_generator = ( 126.5 , 116.5 , 2.0 ) 0 bin 80 80

// Doors
DECLARE_DOOR_INFO ( 969 , 976 , 3 )

DOOR_DATA srs_entrance_door = DOUBLE ( 93 , 103 , 2 ) ( 93.0 , 103.0 , 2.0 , 0.0 , 0.0 ) BOTTOM 0 ANY_PLAYER CLOSE_WHEN_OPEN_RULE_FAILS 0 NOT_FLIPPED NOT_REVERSED
DOOR_DATA srs_prison_door = DOUBLE ( 88 , 90 , 2 ) ( 88.0 , 103.0 , 2.0 , 0.0 , 0.0 ) LEFT 0 ANY_PLAYER CLOSE_WHEN_OPEN_RULE_FAILS 0 NOT_FLIPPED NOT_REVERSED

// Cranes
	// Prison crane, does fuck all
CRANE_DATA srs_crane1 = ( 89.5 , 121.5 ) 195 NO_HOMECRANE
	// Car crusher
		// Crusher part 1 (destroy car)
CRANE_DATA srs_crane2 = ( 122.5 , 110.5 ) 225 NO_HOMECRANE FIRST ( 122.5 , 113.5 ) 270
CRANE_DATA srs_crane3 = ( 125.5 , 113.5 ) 315 srs_crane2 SECOND ( 128.5 , 112.5 ) 0

// Crushers
CRUSHER srs_crusher1 = ( 122.5 , 113.5 )

// Decide what cars go on crusher!
DECLARE_POWERUP_CARLIST ( van , gunjeep , stratos , alfa , fiat , sprite , edsel , dart , vtype , morris , monster , jeffrey , copcar , jeep , stypecab , wbtwin , stingray , edselfbi , stype )
// Set generator for crush car bonus
DECLARE_CRANE_POWERUP ( srs_crane3 , crusher_generator , 128 , 114 , 2 )

// Destructors
DESTRUCTOR srs_crusher_destructor_in = ( 128.5 , 115.5 , 2.0 ) ( 1.0 , 0.2 )
DESTRUCTOR srs_crusher_destructor_out = ( 127.5 , 116.5 , 2.0 ) ( 1.0 , 1.0 )
DESTRUCTOR srs_crusher_destructor_remove = ( 118.5 , 116.5 , 2.0 ) ( 0.2 , 1.0 )

// Conveyors
CONVEYOR srs_crusher_in = ( 128.5 , 113.5 , 2.0 ) ( 1.0 , 4.0 ) 0 1
CONVEYOR srs_crusher_out = ( 122.5 , 116.5 , 2.0 ) ( 9.0 , 1.0 ) -1 0

SET_GANG_INFO ( sci_gang , 7 , pistol , machine_gun , machine_gun , 0 , 0.0 , 0.0 , 0.0 , 0 , STRATOS , 10 )

MAP_ZONE Luca = ( 1000 , 300 , 500 , 50 , 1000 , 100 , 100 , 200 , 400 , 100 , 150 )
MAP_ZONE Luca_Stadium = ( 0 , 0 , 0 , 0 , 1000 , 200 , 0 , 100 , 0 , 100 , 0 )
MAP_ZONE SRS_Research_Center = ( 0 , 0 , 0 , 0 , 1000 , 0 , 0 , 0 , 1000 , 0 , 0 )

DECLARE_POLICELEVEL ( 4 )

COUNTER neverends = 1
COUNTER playerdied = 0
COUNTER door1_destroyed = 0
COUNTER door2_destroyed = 0
COUNTER got_bus = 0
COUNTER at_location = 0 // 86.5 , 99.5
COUNTER prisoners_in_bus = 0
COUNTER car_stopped = 0
COUNTER finished = 0

LEVELSTART

SET_CHAR_GRAPHIC_TYPE ( p1 , DUMMY_GRAPHIC , 33 )
SET_CHAR_GRAPHIC_TYPE ( besaid_keeper , DUMMY_GRAPHIC , 32 )
SET_CHAR_GRAPHIC_TYPE ( besaid01 , DUMMY_GRAPHIC , 32 )
SET_CHAR_GRAPHIC_TYPE ( besaid02 , DUMMY_GRAPHIC , 32 )
SET_CHAR_GRAPHIC_TYPE ( besaid03 , DUMMY_GRAPHIC , 32 )
SET_CHAR_GRAPHIC_TYPE ( besaid04 , DUMMY_GRAPHIC , 32 )
SET_CHAR_GRAPHIC_TYPE ( kilika_keeper , DUMMY_GRAPHIC , 31 )
SET_CHAR_GRAPHIC_TYPE ( kilika01 , DUMMY_GRAPHIC , 31 )
SET_CHAR_GRAPHIC_TYPE ( kilika02 , DUMMY_GRAPHIC , 31 )
SET_CHAR_GRAPHIC_TYPE ( kilika03 , DUMMY_GRAPHIC , 31 )
SET_CHAR_GRAPHIC_TYPE ( kilika04 , DUMMY_GRAPHIC , 31 )

generator_rumble1 = CREATE_SOUND ( 94.5 , 104.5 , 2.0 ) INDUSTRIAL_LOW PLAY_FOREVER END
generator_rumble2 = CREATE_SOUND ( 86.5 , 88.5 , 2.0 ) GENERATOR_RUMBLE PLAY_FOREVER END

GIVE_WEAPON ( p1 , pistol , 50 )
GIVE_WEAPON ( p1 , machine_gun , 25 )
GIVE_WEAPON ( p1 , shotgun , 15 )
GIVE_WEAPON ( p1 , grenade , 5 )
GIVE_WEAPON ( srs_pk01 , pistol )
GIVE_WEAPON ( srs_pk02 , pistol )
GIVE_WEAPON ( srs_pk03 , pistol )
GIVE_WEAPON ( srs_pk04 , pistol )
GIVE_WEAPON ( srs_shoot01 , rocket_launcher )
GIVE_WEAPON ( srs_shoot02 , rocket_launcher )
GIVE_WEAPON ( srs_shoot03 , rocket_launcher )
GIVE_WEAPON ( srs_shoot04 , rocket_launcher )
GIVE_WEAPON ( srs_shoot05 , rocket_launcher )
GIVE_WEAPON ( srs_shoot06 , rocket_launcher )
GIVE_WEAPON ( besaid01 , weapon_12 )
GIVE_WEAPON ( besaid02 , weapon_12 )
GIVE_WEAPON ( besaid03 , weapon_12 )
GIVE_WEAPON ( besaid04 , weapon_12 )
GIVE_WEAPON ( kilika01 , weapon_12 )
GIVE_WEAPON ( kilika02 , weapon_12 )
GIVE_WEAPON ( kilika03 , weapon_12 )
GIVE_WEAPON ( kilika04 , weapon_12 )
SET_CHAR_THREAT_SEARCH ( srs_shoot01 , AREA )
SET_CHAR_THREAT_SEARCH ( srs_shoot02 , AREA )
SET_CHAR_THREAT_SEARCH ( srs_shoot03 , AREA )
SET_CHAR_THREAT_SEARCH ( srs_shoot04 , AREA )
SET_CHAR_THREAT_SEARCH ( srs_shoot05 , AREA )
SET_CHAR_THREAT_SEARCH ( srs_shoot06 , AREA )
SET_CHAR_THREAT_REACTION ( srs_shoot01 , REACT_AS_NORMAL )
SET_CHAR_THREAT_REACTION ( srs_shoot02 , REACT_AS_NORMAL )
SET_CHAR_THREAT_REACTION ( srs_shoot03 , REACT_AS_NORMAL )
SET_CHAR_THREAT_REACTION ( srs_shoot04 , REACT_AS_NORMAL )
SET_CHAR_THREAT_REACTION ( srs_shoot05 , REACT_AS_NORMAL )
SET_CHAR_THREAT_REACTION ( srs_shoot06 , REACT_AS_NORMAL )
SET_CHAR_OBJECTIVE ( srs_shoot01 , GUARD_SPOT )
SET_CHAR_OBJECTIVE ( srs_shoot02 , GUARD_SPOT )
SET_CHAR_OBJECTIVE ( srs_shoot03 , GUARD_SPOT )
SET_CHAR_OBJECTIVE ( srs_shoot04 , GUARD_SPOT )
SET_CHAR_OBJECTIVE ( srs_shoot05 , GUARD_SPOT )
SET_CHAR_OBJECTIVE ( srs_shoot06 , GUARD_SPOT )

KILL_CHAR ( guard01 )
KILL_CHAR ( guard02 )
KILL_CHAR ( guard03 )

SET_CHAR_OBJECTIVE ( besaid01 , DESTROY_OBJECT , football )
SET_CHAR_OBJECTIVE ( besaid02 , DESTROY_OBJECT , football )
SET_CHAR_OBJECTIVE ( besaid03 , DESTROY_OBJECT , football )
SET_CHAR_OBJECTIVE ( besaid04 , DESTROY_OBJECT , football )
SET_CHAR_OBJECTIVE ( kilika01 , DESTROY_OBJECT , football )
SET_CHAR_OBJECTIVE ( kilika02 , DESTROY_OBJECT , football )
SET_CHAR_OBJECTIVE ( kilika03 , DESTROY_OBJECT , football )
SET_CHAR_OBJECTIVE ( kilika04 , DESTROY_OBJECT , football )

MAKE_DOOR_MANUAL ( srs_entrance_door )
MAKE_DOOR_MANUAL ( srs_prison_door )

DISPLAY_BRIEF ( 1019 )
DISPLAY_BRIEF ( 1020 )
DISPLAY_BRIEF ( 1021 )
DELAY_HERE ( 750 )
EXPLODE_LARGE ( besaid_keeper )
EXPLODE_LARGE ( besaid01 )
EXPLODE_LARGE ( besaid02 )
EXPLODE_LARGE ( besaid03 )
EXPLODE_LARGE ( besaid04 )
EXPLODE_LARGE ( kilika_keeper )
EXPLODE_LARGE ( kilika01 )
EXPLODE_LARGE ( kilika02 )
EXPLODE_LARGE ( kilika03 )
EXPLODE_LARGE ( kilika04 )
DISPLAY_BRIEF ( 1022 )
DISPLAY_BRIEF ( 1023 )
DELAY_HERE ( 300 )
POINT_ARROW_AT ( arrow01 , generator1 )
SET_CHAR_THREAT_SEARCH ( srs_pk01 , AREA_PLAYER_ONLY )
SET_CHAR_THREAT_SEARCH ( srs_pk02 , AREA_PLAYER_ONLY )
SET_CHAR_THREAT_SEARCH ( srs_pk03 , AREA_PLAYER_ONLY )
SET_CHAR_THREAT_SEARCH ( srs_pk04 , AREA_PLAYER_ONLY )
SET_CHAR_THREAT_REACTION ( srs_pk01 , REACT_AS_NORMAL )
SET_CHAR_THREAT_REACTION ( srs_pk02 , REACT_AS_NORMAL )
SET_CHAR_THREAT_REACTION ( srs_pk03 , REACT_AS_NORMAL )
SET_CHAR_THREAT_REACTION ( srs_pk04 , REACT_AS_NORMAL )
SET_CHAR_OBJECTIVE ( srs_pk01 , KILL_CHAR_ON_FOOT , p1 )
SET_CHAR_OBJECTIVE ( srs_pk02 , KILL_CHAR_ON_FOOT , p1 )
SET_CHAR_OBJECTIVE ( srs_pk03 , KILL_CHAR_ON_FOOT , p1 )
SET_CHAR_OBJECTIVE ( srs_pk04 , KILL_CHAR_ON_FOOT , p1 )
ADD_CHAR_TO_GANG ( srs_pk01 , sci_gang )
ADD_CHAR_TO_GANG ( srs_pk02 , sci_gang )
ADD_CHAR_TO_GANG ( srs_pk03 , sci_gang )
ADD_CHAR_TO_GANG ( srs_pk04 , sci_gang )

WHILE_EXEC ( neverends = 1 )

	IF ( ( CHECK_OBJ_MODEL ( generator1 , POWERGEN_DEAD ) ) AND ( door1_destroyed = 0 ) )
	generator_lose_power = CREATE_SOUND ( 94.5 , 104.5 , 2.0 ) GENERATOR_LOSE_POWER PLAY_INSTANT END
	DELETE_ITEM ( generator_rumble1 )
	DELAY_HERE ( 60 )
	door_opening = CREATE_SOUND ( 93.5 , 103.5 , 2.0 ) GARAGE_OPEN PLAY_INSTANT END
	OPEN_DOOR ( srs_entrance_door )
	DISPLAY_BRIEF ( 1024 )
	SET_GANG_CHAR_RESPECT ( sci_gang , p1 , -5 )
	SET door1_destroyed = 1
	ENDIF

	IF ( ( CHECK_OBJ_MODEL ( generator1 , POWERGEN_DEAD ) ) AND ( door1_destroyed = 1 ) )
	REMOVE_ARROW ( arrow01 )	
	POINT_ARROW_AT ( arrow01 , generator2 )
	ENDIF

	IF ( ( CHECK_OBJ_MODEL ( generator2 , POWERGEN_DEAD ) ) AND ( door2_destroyed = 0 ) )
	REMOVE_ARROW ( arrow01 )
	DELETE_ITEM ( generator_rumble2 )
	DELAY_HERE ( 60 )
	door_opening = CREATE_SOUND ( 87.5 , 88.5 , 2.0 ) GARAGE_OPEN PLAY_INSTANT END
	OPEN_DOOR ( srs_prison_door )
	CHANGE_GANG_CHAR_RESPECT ( sci_gang , p1 , 10 )
	DISPLAY_BRIEF ( 1025 )
	srs_bus = CREATE_CAR ( 135.5 , 89.5 , 2.0 ) 10 0 VAN END
	SET door2_destroyed = 1
	ENDIF

	IF ( ( CHECK_OBJ_MODEL ( generator2 , POWERGEN_DEAD ) ) AND ( door2_destroyed = 1 ) )
	POINT_ARROW_AT ( arrow01 , srs_bus )
	ENDIF

	IF ( HAS_CHARACTER_DIED ( p1 ) )
	SET playerdied = 1
	DELAY_HERE ( 150 )
	SET_CHAR_OBJECTIVE ( srs_shoot01 , KILL_CHAR_ON_FOOT , p1 )
	SET_CHAR_OBJECTIVE ( srs_shoot02 , KILL_CHAR_ON_FOOT , p1 )
	SET_CHAR_OBJECTIVE ( srs_shoot03 , KILL_CHAR_ON_FOOT , p1 )
	SET_CHAR_OBJECTIVE ( srs_shoot04 , KILL_CHAR_ON_FOOT , p1 )
	SET_CHAR_OBJECTIVE ( srs_shoot05 , KILL_CHAR_ON_FOOT , p1 )
	SET_CHAR_OBJECTIVE ( srs_shoot06 , KILL_CHAR_ON_FOOT , p1 )
	ENDIF

	IF ( playerdied = 1 )
	SET_CHAR_GRAPHIC_TYPE ( p1 , DUMMY_GRAPHIC , 33 )
	ENDIF

	IF ( IS_CHARACTER_IN_CAR ( p1 , srs02 ) )
	EXPLODE_LARGE ( srs02 )
	ENDIF

	IF ( IS_CHARACTER_IN_CAR ( p1 , srs03 ) )
	EXPLODE_LARGE ( srs03 )
	ENDIF

	IF ( ( IS_CHARACTER_IN_CAR ( p1 , srs_bus ) ) AND ( got_bus = 0 ) )
	SET got_bus = 1
	prisoner01 = CREATE_CHAR ( 84.5 , 97.5 , 2.0 ) 45 270 CRIMINAL_TYPE2 END
	prisoner02 = CREATE_CHAR ( 85.5 , 97.5 , 2.0 ) 46 270 CRIMINAL_TYPE2 END
	prisoner03 = CREATE_CHAR ( 86.5 , 97.5 , 2.0 ) 47 270 CRIMINAL_TYPE2 END
	prisoner04 = CREATE_CHAR ( 87.5 , 97.5 , 2.0 ) 48 270 CRIMINAL_TYPE2 END
	prisoner05 = CREATE_CHAR ( 88.5 , 97.5 , 2.0 ) 49 270 CRIMINAL_TYPE2 END
	prisoner06 = CREATE_CHAR ( 89.5 , 97.5 , 2.0 ) 50 270 CRIMINAL_TYPE2 END
	prisoner07 = CREATE_CHAR ( 90.5 , 97.5 , 2.0 ) 51 270 CRIMINAL_TYPE2 END
	prisoner08 = CREATE_CHAR ( 91.5 , 97.5 , 2.0 ) 52 270 CRIMINAL_TYPE2 END
	DISPLAY_BRIEF ( 1026 )
	REMOVE_ARROW ( arrow01 )
	SET_CHAR_GRAPHIC_TYPE ( prisoner01 , DUMMY_GRAPHIC , 45 )
	SET_CHAR_GRAPHIC_TYPE ( prisoner02 , DUMMY_GRAPHIC , 46 )
	SET_CHAR_GRAPHIC_TYPE ( prisoner03 , DUMMY_GRAPHIC , 47 )
	SET_CHAR_GRAPHIC_TYPE ( prisoner04 , DUMMY_GRAPHIC , 48 )
	SET_CHAR_GRAPHIC_TYPE ( prisoner05 , DUMMY_GRAPHIC , 49 )
	SET_CHAR_GRAPHIC_TYPE ( prisoner06 , DUMMY_GRAPHIC , 50 )
	SET_CHAR_GRAPHIC_TYPE ( prisoner07 , DUMMY_GRAPHIC , 51 )
	SET_CHAR_GRAPHIC_TYPE ( prisoner08 , DUMMY_GRAPHIC , 52 )
	ADD_GROUP_TO_CHARACTER ( prisoner01 , 0 )
	ADD_EXISTING_CHAR_TO_GROUP ( prisoner01 , prisoner02 )
	ADD_EXISTING_CHAR_TO_GROUP ( prisoner01 , prisoner03 )
	ADD_EXISTING_CHAR_TO_GROUP ( prisoner01 , prisoner04 )
	ADD_EXISTING_CHAR_TO_GROUP ( prisoner01 , prisoner05 )
	ADD_EXISTING_CHAR_TO_GROUP ( prisoner01 , prisoner06 )
	ADD_EXISTING_CHAR_TO_GROUP ( prisoner01 , prisoner07 )
	ADD_EXISTING_CHAR_TO_GROUP ( prisoner01 , prisoner08 )
	POINT_ARROW_AT ( arrow01 , 88.5 , 99.5 , 2.0 )
	ENDIF

	IF ( got_bus = 1 )
	REMOVE_ARROW ( arrow01 )
	SET got_bus = 2
	ENDIF

	IF ( got_bus = 2 )
	POINT_ARROW_AT ( arrow01 , 88.5 , 99.5 , 2.0 )
	ENDIF

	IF ( got_bus = 3 )
	REMOVE_ARROW ( arrow01 )
	ENDIF

IF ( ( ( IS_CAR_IN_BLOCK ( srs_bus , 88.5 , 99.5 , 2.0 ) )
AND ( got_bus = 2 ) )
AND ( at_location = 0 ) )
	SET at_location = 1
	SET got_bus = 3
	DISPLAY_BRIEF ( 1029 )
	REMOVE_ARROW ( arrow01 )
	SET finished = 1
	SET prisoners_in_bus = 1
	SET at_location = 2
	SET_CHAR_OBJECTIVE ( prisoner01 , ENTER_CAR_AS_PASSENGER , srs_bus )
	DISPLAY_BRIEF ( 1027 )
	finish_van = CREATE_CAR ( 145.5 , 89.5 , 2.0 ) 2 180 VAN END
	POINT_ARROW_AT ( arrow01 , 142.5 , 89.5 , 2.0 )
	ENDIF

	/*IF ( ( ( at_location = 1 )
AND ( prisoners_in_bus = 0 ) )
AND ( got_bus = 3 ) )
	
	ENDIF*/

IF ( ( ( IS_CAR_IN_BLOCK ( srs_bus , 142.5 , 89.5 , 2.0 ) )
AND ( finished = 1 ) )
AND ( at_location = 2 ) )
	SET finished = 2
	DISPLAY_BRIEF ( 1028 )
	LEVEL_END_POINT_ARROW_AT ( arrow_end , finish_van )
	ENDIF

ENDWHILE

LEVELEND