PLAYER_PED player1 = ( 92.5 , 102.5 , 3.0 ) 7 45
PLAYER_PED player2 = ( 98.5 , 102.5 , 3.0 ) 9 0
PLAYER_PED player3 = ( 104.5 , 102.5 , 3.0 ) 5 315
PLAYER_PED player4 = ( 92.5 , 111.5 , 3.0 ) 10 225
PLAYER_PED player5 = ( 98.5 , 111.5 , 3.0 ) 11 180
PLAYER_PED player6 = ( 104.5 , 111.5 , 3.0 ) 13 135
 
COUNTER loop = 1
COUNTER plr1_bomb  // Playerx bomb timers
COUNTER plr2_bomb  // "       "    "     
COUNTER plr3_bomb  // "       "    "     
COUNTER plr4_bomb  // "       "    "     
COUNTER plr5_bomb  // "       "    "     
COUNTER plr6_bomb  // "       "    "     
COUNTER plr_it = 0  // What player is 'IT', 0 = no player is 'IT' temporarily
COUNTER prev_it = 0  // Who was the player that was 'IT' previous to current player who is 'IT'.  *Important for keeping track of who to add_score to.
COUNTER six_count = 0  // This is a counter that will keep counting to 6 to help seem to randomize who is 'IT'
COUNTER reset_delay = 0  //  counter used as a delay timer in game cycles before assigning a player to be 'IT'
ONSCREEN_COUNTER player1_timer  
ONSCREEN_COUNTER player2_timer
ONSCREEN_COUNTER player3_timer
ONSCREEN_COUNTER player4_timer
 
GENERATOR health = ( 98.5 , 107.5 , 2.0 ) 0 COLLECT_30 0 0 99
GENERATOR elecbat1 = ( 92.5 , 102.5 , 2.0 ) 0 COLLECT_07 0 0 99
GENERATOR elecbat2 = ( 98.5 , 102.5 , 2.0 ) 0 COLLECT_07 0 0 99
GENERATOR elecbat3 = ( 104.5 , 102.5 , 2.0 ) 0 COLLECT_07 0 0 99
GENERATOR elecbat4 = ( 92.5 , 111.5 , 2.0 ) 0 COLLECT_07 0 0 99
GENERATOR elecbat5 = ( 98.5 , 111.5 , 2.0 ) 0 COLLECT_07 0 0 99
GENERATOR elecbat6 = ( 104.5 , 111.5 , 2.0 ) 0 COLLECT_07 0 0 99
 
reinit_plr_bomb:  // Subroutine to reinitialize playerx bomb timers

                SET plr1_bomb = 0 
                SET plr2_bomb = 0
                SET plr3_bomb = 0
                SET plr4_bomb = 0
                SET plr5_bomb = 0
                SET plr6_bomb = 0
RETURN

LEVELSTART
SET_AMBIENT_LEVEL ( 0.33 , 3 )
ADD_ONSCREEN_COUNTER ( player1_timer , plr1_bomb )
ADD_ONSCREEN_COUNTER ( player2_timer , plr2_bomb )
ADD_ONSCREEN_COUNTER ( player3_timer , plr3_bomb )
ADD_ONSCREEN_COUNTER ( player4_timer , plr4_bomb )
 
SWITCH_GENERATOR ( health , ON )
SWITCH_GENERATOR ( elecbat1 , ON )
SWITCH_GENERATOR ( elecbat2 , ON )
SWITCH_GENERATOR ( elecbat3 , ON )
SWITCH_GENERATOR ( elecbat4 , ON )
SWITCH_GENERATOR ( elecbat5 , ON )
SWITCH_GENERATOR ( elecbat6 , ON )

MAP_ZONE batgang = ( 0 , 0 , 0 , 0 , 800 , 0 , 0 , 0 , 800 , 0 , 0)//Tells game to spawn only gang members inside the arena
SET_GANG_INFO ( batgang , 2 , ELECTRO_BATON , ELECTRO_BATON , ELECTRO_BATON , 8 ,98.5 , 107.5 , 2.0 , 0 , SWATVAN , 36 )//Tells the game to create the electrobatoners gang inside the arena

WHILE_EXEC ( loop = 1 )//Main loop

//  6 COUNT LOOPER FOR RANDOM PLAYER 'IT' SELECTION ////////////////////////////////////////////////

    ++six_count  // keeps counting to 6 used to help randomize who is 'IT'
    IF ( six_count = 7 )
        SET six_count = 1
    ENDIF
 
//  WHEN NO ONE IS 'IT' USE THE 6 COUNT SEED TO SELECT NEXT 'IT'  //////////////////////////////////

    IF ( plr_it = 0 )  // If no player is currently 'IT'

       //The following commands will change the gang respect to players to -5, so they always try to shoot the players to slow them down
       IF ( CHECK_CHARACTER_HEALTH ( player1 , 0 ) )  // set gang to hate all players
          CHANGE_GANG_CHAR_RESPECT ( batgang , player1 , -5 )
       ENDIF
       IF ( CHECK_CHARACTER_HEALTH ( player2 , 0 ) )
          CHANGE_GANG_CHAR_RESPECT ( batgang , player2 , -5 )
       ENDIF
       IF ( CHECK_CHARACTER_HEALTH ( player3 , 0 ) )
          CHANGE_GANG_CHAR_RESPECT ( batgang , player3 , -5 )
       ENDIF
       IF ( CHECK_CHARACTER_HEALTH ( player4 , 0 ) )
          CHANGE_GANG_CHAR_RESPECT ( batgang , player4 , -5 )
       ENDIF
       IF ( CHECK_CHARACTER_HEALTH ( player5 , 0 ) )
          CHANGE_GANG_CHAR_RESPECT ( batgang , player5 , -5 )
       ENDIF
       IF ( CHECK_CHARACTER_HEALTH ( player6 , 0 ) )
          CHANGE_GANG_CHAR_RESPECT ( batgang , player6 , -5 )
       ENDIF

       IF ( reset_delay = 0 )  // If the reset_delay is OFF = 0
            DISPLAY_BRIEF_NOW ( 3132 ) //Randomizing next bomb holder..
            SET reset_delay = 1  // turn reset_delay ON = 1
            GOSUB reinit_plr_bomb:
        ENDIF
        IF ( reset_delay > 0 )  // increment reset_delay once turned ON >= 1 used to create a delay in game cycles before new player is randomly chosen to be 'IT'
            ++reset_delay
        ENDIF

        IF ( reset_delay > 179 )  // reset_delay game cycle count limit, delay before someone is assigned to be 'IT'        
           SET reset_delay = 179  //  reset_delay limit should match the above line, stop game from counting higher
           IF ( ( CHECK_CHARACTER_HEALTH ( player6 , 0 ) ) AND ( six_count = 6 ) )
												 IF ( NOT ( prev_it = 6 ) )  // if player is alive and six_counter matches player number and this player wasn't just killed being 'IT'
                SET plr_it = 6  // assign player to be 'IT'
                CHANGE_GANG_CHAR_RESPECT ( batgang , player6 , 5 )  // make batgang respect player with bomb
                DISPLAY_BRIEF_NOW ( 3138 ) //Player6 got the bomb
                SET reset_delay = 0  // reinitialize reset_delay
             ENDIF
           ENDIF
           IF ( ( CHECK_CHARACTER_HEALTH ( player5 , 0 ) ) AND ( six_count = 5 ) )
												 IF ( NOT ( prev_it = 5 ) )
                SET plr_it = 5
                CHANGE_GANG_CHAR_RESPECT ( batgang , player5 , 5 )
                DISPLAY_BRIEF_NOW ( 3137 ) //Player5 got the bomb
                SET reset_delay = 0
             ENDIF
           ENDIF
           IF ( ( CHECK_CHARACTER_HEALTH ( player4 , 0 ) ) AND ( six_count = 4 ) )
												 IF ( NOT ( prev_it = 4 ) )
                SET plr_it = 4
                CHANGE_GANG_CHAR_RESPECT ( batgang , player4 , 5 )
                DISPLAY_BRIEF_NOW ( 3136 ) //Player4 got the bomb
                SET reset_delay = 0
             ENDIF
           ENDIF
           IF ( ( CHECK_CHARACTER_HEALTH ( player3 , 0 ) ) AND ( six_count = 3 ) )
												 IF ( NOT ( prev_it = 3 ) )
                SET plr_it = 3
                CHANGE_GANG_CHAR_RESPECT ( batgang , player3 , 5 )
                DISPLAY_BRIEF_NOW ( 3135 ) //Player3 got the bomb
                SET reset_delay = 0
             ENDIF
           ENDIF
           IF ( ( CHECK_CHARACTER_HEALTH ( player2 , 0 ) ) AND ( six_count = 2 ) )
              IF ( NOT ( prev_it = 2 ) )
                 SET plr_it = 2
                 CHANGE_GANG_CHAR_RESPECT ( batgang , player2 , 5 )
                 DISPLAY_BRIEF_NOW ( 3134 ) //Player2 got the bomb
                 SET reset_delay = 0
              ENDIF
           ENDIF
           IF ( (  CHECK_CHARACTER_HEALTH ( player1 , 0 ) ) AND ( six_count = 1 ) )
												 IF ( NOT ( prev_it = 1 ) )  
                SET plr_it = 1  
                CHANGE_GANG_CHAR_RESPECT ( batgang , player1 , 5 )
                DISPLAY_BRIEF_NOW ( 3133 ) //Player1 got the bomb
                SET reset_delay = 0
             ENDIF
           ENDIF
        ENDIF
    ENDIF
 
//  PLAYER1 ROUTINE TO CHECK IF PUNCHED BY ANOTHER PLAYER AND EXPLODE IF BOMB IS HELD TOO LONG /////

    IF ( CHECK_CHARACTER_HEALTH ( player1 , 0 ) )
        
        IF ( CHECK_CHARACTER_HEALTH ( player2 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player1 , player2 ) ) AND ( plr_it = 2 ) )  // has player2 being 'IT' punched player1
                  SET prev_it = 2  // store previous player being 'IT' for add_score handling
                  SET plr_it = 1  // make this player newly 'IT'
                  CHANGE_GANG_CHAR_RESPECT ( batgang , player2 , -5 )  // make gang hate player2 again
                  CHANGE_GANG_CHAR_RESPECT ( batgang , player1 , 5 )  // make gang respect player1 again
                  GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player3 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player1 , player3 ) ) AND ( plr_it = 3 ) )
                  SET prev_it = 3
                  SET plr_it = 1
                  CHANGE_GANG_CHAR_RESPECT ( batgang , player3 , -5 )
                  CHANGE_GANG_CHAR_RESPECT ( batgang , player1 , 5 )
                  GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player4 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player1 , player4 ) ) AND ( plr_it = 4 ) )
                  SET prev_it = 4
                  SET plr_it = 1
                  CHANGE_GANG_CHAR_RESPECT ( batgang , player4 , -5 )
                  CHANGE_GANG_CHAR_RESPECT ( batgang , player1 , 5 )
                  GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player5 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player1 , player5 ) ) AND ( plr_it = 5 ) )
                  SET prev_it = 5
                  SET plr_it = 1
                  CHANGE_GANG_CHAR_RESPECT ( batgang , player5 , -5 )
                  CHANGE_GANG_CHAR_RESPECT ( batgang , player1 , 5 )
                  GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player6 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player1 , player6 ) ) AND ( plr_it = 6 ) )
                  SET prev_it = 6
                  SET plr_it = 1
                  CHANGE_GANG_CHAR_RESPECT ( batgang , player6 , -5 )
                  CHANGE_GANG_CHAR_RESPECT ( batgang , player1 , 5 )
                  GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
 
        IF ( plr_it = 1 )  // is player1 'IT'
           IF ( plr1_bomb = 0 )  // is the plr1_bomb counter OFF = 0
             SET plr1_bomb = 450  // turn ON = 1plr1_bomb counter
           ENDIF
            IF ( plr1_bomb > 0 ) // is plr1_bomb counter ON >= 1
                --plr1_bomb  // increment plr1_bomb counter
                IF ( plr1_bomb < 1 )  // plr1_bomb count game cycle limit.  Adjust this value to control when 'IT' player explodes.
                    IF ( CHECK_SCORE_GREATER ( player1 , 999 ) )  // If 'IT' player's score is at least 1000
                       ADD_SCORE ( player1, -1000 )  // punish exploding player's score
                    ENDIF
                    IF ( prev_it = 2 )
                        ADD_SCORE ( player2, 2000 )  // if previous 'IT' player was player2, add 2000 to their score
                    ENDIF
                    IF ( prev_it = 3 )
                        ADD_SCORE ( player3, 2000 )
                    ENDIF
                    IF ( prev_it = 4 )
                        ADD_SCORE ( player4, 2000 )
                    ENDIF
                    IF ( prev_it = 5 )
                        ADD_SCORE ( player5, 2000 )
                    ENDIF
                    IF ( prev_it = 6 )
                        ADD_SCORE ( player6, 2000 )
                    ENDIF
                    EXPLODE_LARGE ( player1 )  // Medium explosion of player1 once plr1_bomb cycle limit reached
                    SET plr_it = 0  // reinititialize plr_it.  No body is 'IT' for a short time now.  See above plr_it = 0 IF statement.
                ENDIF
            ENDIF
        ENDIF
    ENDIF
 
//  PLAYER2 ROUTINE TO CHECK IF PUNCHED BY ANOTHER PLAYER AND EXPLODE IF BOMB IS HELD TOO LONG /////
 
    IF ( CHECK_CHARACTER_HEALTH ( player2 , 0 ) )
 
        IF ( CHECK_CHARACTER_HEALTH ( player1 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player2, player1 ) ) AND ( plr_it = 1 ) )
                SET prev_it = 1
                SET plr_it = 2
                CHANGE_GANG_CHAR_RESPECT ( batgang , player1 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player2 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player3 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player2, player3 ) ) AND ( plr_it = 3 ) )
                SET prev_it = 3
                SET plr_it = 2
                CHANGE_GANG_CHAR_RESPECT ( batgang , player3 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player2 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player4 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player2, player4 ) ) AND ( plr_it = 4 ) )
                SET prev_it = 4
                SET plr_it = 2
                CHANGE_GANG_CHAR_RESPECT ( batgang , player4 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player2 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player5 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player2, player5 ) ) AND ( plr_it = 5 ) )
                SET prev_it = 5
                SET plr_it = 2
                CHANGE_GANG_CHAR_RESPECT ( batgang , player5 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player2 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player6 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player2, player6 ) ) AND ( plr_it = 6 ) )
                SET prev_it = 6
                SET plr_it = 2
                CHANGE_GANG_CHAR_RESPECT ( batgang , player6 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player2 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
 
        IF ( plr_it = 2 )
            IF ( plr2_bomb = 0 )
                SET plr2_bomb = 450
            ENDIF
            IF ( plr2_bomb > 0 )
                --plr2_bomb
                IF ( plr2_bomb < 1 )
                    IF ( CHECK_SCORE_GREATER ( player2 , 999 ) )
                       ADD_SCORE ( player2, -1000 )
                    ENDIF
                    IF ( prev_it = 1 )
                        ADD_SCORE ( player1, 2000 )
                    ENDIF
                    IF ( prev_it = 3 )
                        ADD_SCORE ( player3, 2000 )
                    ENDIF
                    IF ( prev_it = 4 )
                        ADD_SCORE ( player4, 2000 )
                    ENDIF
                    IF ( prev_it = 5 )
                        ADD_SCORE ( player5, 2000 )
                    ENDIF
                    IF ( prev_it = 6 )
                        ADD_SCORE ( player6, 2000 )
                    ENDIF
                    EXPLODE_LARGE ( player2 )
                    SET plr_it = 0
                ENDIF
            ENDIF
        ENDIF
    ENDIF

//  PLAYER3 ROUTINE TO CHECK IF PUNCHED BY ANOTHER PLAYER AND EXPLODE IF BOMB IS HELD TOO LONG /////

    IF ( CHECK_CHARACTER_HEALTH ( player3 , 0 ) )
 
        IF ( CHECK_CHARACTER_HEALTH ( player1 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player3, player1 ) ) AND ( plr_it = 1 ) )
                SET prev_it = 1
                SET plr_it = 3
                CHANGE_GANG_CHAR_RESPECT ( batgang , player1 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player3 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player2 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player3, player2 ) ) AND ( plr_it = 2 ) )
                SET prev_it = 2
                SET plr_it = 3
                CHANGE_GANG_CHAR_RESPECT ( batgang , player2 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player3 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player4 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player3, player4 ) ) AND ( plr_it = 4 ) )
                SET prev_it = 4
                SET plr_it = 3
                CHANGE_GANG_CHAR_RESPECT ( batgang , player4 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player3 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player5 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player3, player5 ) ) AND ( plr_it = 5 ) )
                SET prev_it = 5
                SET plr_it = 3
                CHANGE_GANG_CHAR_RESPECT ( batgang , player5 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player3 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player6 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player3, player6 ) ) AND ( plr_it = 6 ) )
                SET prev_it = 6
                SET plr_it = 3
                CHANGE_GANG_CHAR_RESPECT ( batgang , player6 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player3 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF

        IF ( plr_it = 3 )
            IF ( plr3_bomb = 0 )
                SET plr3_bomb = 450
            ENDIF
            IF ( plr3_bomb > 0 )
                --plr3_bomb
                IF ( plr3_bomb < 1 )
                    IF ( CHECK_SCORE_GREATER ( player3 , 999 ) )
                       ADD_SCORE ( player3, -1000 )
                    ENDIF
                    IF ( prev_it = 1 )
                        ADD_SCORE ( player1, 2000 )
                    ENDIF
                    IF ( prev_it = 2 )
                        ADD_SCORE ( player2, 2000 )
                    ENDIF
                    IF ( prev_it = 4 )
                        ADD_SCORE ( player4, 2000 )
                    ENDIF
                    IF ( prev_it = 5 )
                        ADD_SCORE ( player5, 2000 )
                    ENDIF
                    IF ( prev_it = 6 )
                        ADD_SCORE ( player6, 2000 )
                    ENDIF
                    EXPLODE_LARGE ( player3 )
                    SET plr_it = 0
                ENDIF
            ENDIF
        ENDIF
    ENDIF
 
//  PLAYER4 ROUTINE TO CHECK IF PUNCHED BY ANOTHER PLAYER AND EXPLODE IF BOMB IS HELD TOO LONG /////

    IF ( CHECK_CHARACTER_HEALTH ( player4 , 0 ) )
 
        IF ( CHECK_CHARACTER_HEALTH ( player1 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player4, player1 ) ) AND ( plr_it = 1 ) )
                SET prev_it = 1
                SET plr_it = 4
                CHANGE_GANG_CHAR_RESPECT ( batgang , player1 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player4 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player2 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player4, player2 ) ) AND ( plr_it = 2 ) )
                SET prev_it = 2
                SET plr_it = 4
                CHANGE_GANG_CHAR_RESPECT ( batgang , player2 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player4 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player3 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player4, player3 ) ) AND ( plr_it = 3 ) )
                SET prev_it = 3
                SET plr_it = 4
                CHANGE_GANG_CHAR_RESPECT ( batgang , player3 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player4 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player5 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player4, player5 ) ) AND ( plr_it = 5 ) )
                SET prev_it = 5
                SET plr_it = 4
                CHANGE_GANG_CHAR_RESPECT ( batgang , player5 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player4 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player6 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player4, player6 ) ) AND ( plr_it = 6 ) )
                SET prev_it = 6
                SET plr_it = 4
                CHANGE_GANG_CHAR_RESPECT ( batgang , player6 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player4 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
 
        IF ( plr_it = 4 )
            IF ( plr4_bomb = 0 )
                SET plr4_bomb = 450
            ENDIF
            IF ( plr4_bomb > 0 )
                --plr4_bomb
                IF ( plr4_bomb < 1 )
                    IF ( CHECK_SCORE_GREATER ( player4 , 999 ) )
                       ADD_SCORE ( player4, -1000 )
                    ENDIF
                    IF ( prev_it = 1 )
                        ADD_SCORE ( player1, 2000 )
                    ENDIF
                    IF ( prev_it = 2 )
                        ADD_SCORE ( player2, 2000 )
                    ENDIF
                    IF ( prev_it = 3 )
                        ADD_SCORE ( player3, 2000 )
                    ENDIF
                    IF ( prev_it = 5 )
                        ADD_SCORE ( player5, 2000 )
                    ENDIF
                    IF ( prev_it = 6 )
                        ADD_SCORE ( player6, 2000 )
                    ENDIF
                    EXPLODE_LARGE ( player4 )
                    SET plr_it = 0
                ENDIF
            ENDIF
        ENDIF
    ENDIF

//  PLAYER5 ROUTINE TO CHECK IF PUNCHED BY ANOTHER PLAYER AND EXPLODE IF BOMB IS HELD TOO LONG /////

    IF ( CHECK_CHARACTER_HEALTH ( player5 , 0 ) )
 
        IF ( CHECK_CHARACTER_HEALTH ( player1 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player5, player1 ) ) AND ( plr_it = 1 ) )
                SET prev_it = 1
                SET plr_it = 5
                CHANGE_GANG_CHAR_RESPECT ( batgang , player1 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player5 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player2 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player5, player2 ) ) AND ( plr_it = 2 ) )
                SET prev_it = 2
                SET plr_it = 5
                CHANGE_GANG_CHAR_RESPECT ( batgang , player2 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player5 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player3 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player5, player3 ) ) AND ( plr_it = 3 ) )
                SET prev_it = 3
                SET plr_it = 5
                CHANGE_GANG_CHAR_RESPECT ( batgang , player3 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player5 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player4 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player5, player4 ) ) AND ( plr_it = 4 ) )
                SET prev_it = 5
                SET plr_it = 5
                CHANGE_GANG_CHAR_RESPECT ( batgang , player4 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player5 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player6 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player5, player6 ) ) AND ( plr_it = 6 ) )
                SET prev_it = 6
                SET plr_it = 5
                CHANGE_GANG_CHAR_RESPECT ( batgang , player6 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player5 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
 
        IF ( plr_it = 5 )
            IF ( plr5_bomb = 0 )
                SET plr5_bomb = 450
            ENDIF
            IF ( plr5_bomb > 0 )
                --plr5_bomb
                IF ( plr5_bomb < 1 )
                    IF ( CHECK_SCORE_GREATER ( player5 , 999 ) )
                       ADD_SCORE ( player5, -1000 )
                    ENDIF
                    IF ( prev_it = 1 )
                        ADD_SCORE ( player1, 2000 )
                    ENDIF
                    IF ( prev_it = 2 )
                        ADD_SCORE ( player2, 2000 )
                    ENDIF
                    IF ( prev_it = 3 )
                        ADD_SCORE ( player3, 2000 )
                    ENDIF
                    IF ( prev_it = 4 )
                        ADD_SCORE ( player4, 2000 )
                    ENDIF
                    IF ( prev_it = 6 )
                        ADD_SCORE ( player6, 2000 )
                    ENDIF
                    EXPLODE_LARGE ( player5 )
                    SET plr_it = 0
                ENDIF
            ENDIF
        ENDIF
    ENDIF

//  PLAYER6 ROUTINE TO CHECK IF PUNCHED BY ANOTHER PLAYER AND EXPLODE IF BOMB IS HELD TOO LONG /////

    IF ( CHECK_CHARACTER_HEALTH ( player6 , 0 ) )
 
        IF ( CHECK_CHARACTER_HEALTH ( player1 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player6, player1 ) ) AND ( plr_it = 1 ) )
                SET prev_it = 1
                SET plr_it = 6
                CHANGE_GANG_CHAR_RESPECT ( batgang , player1 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player6 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player2 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player6, player2 ) ) AND ( plr_it = 2 ) )
                SET prev_it = 2
                SET plr_it = 6
                CHANGE_GANG_CHAR_RESPECT ( batgang , player2 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player6 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player3 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player6, player3 ) ) AND ( plr_it = 3 ) )
                SET prev_it = 3
                SET plr_it = 6
                CHANGE_GANG_CHAR_RESPECT ( batgang , player3 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player6 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player4 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player6, player4 ) ) AND ( plr_it = 4 ) )
                SET prev_it = 5
                SET plr_it = 6
                CHANGE_GANG_CHAR_RESPECT ( batgang , player4 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player6 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
        IF ( CHECK_CHARACTER_HEALTH ( player5 , 0 ) )
            IF ( ( CHECK_CHAR_BEEN_PUNCHED_BY ( player6, player5 ) ) AND ( plr_it = 5 ) )
                SET prev_it = 5
                SET plr_it = 6
                CHANGE_GANG_CHAR_RESPECT ( batgang , player5 , -5 )
                CHANGE_GANG_CHAR_RESPECT ( batgang , player6 , 5 )
                GOSUB reinit_plr_bomb:
            ENDIF
        ENDIF
 
        IF ( plr_it = 6 )
            IF ( plr6_bomb = 0 )
                SET plr6_bomb = 450
            ENDIF
            IF ( plr6_bomb > 0 )
                --plr6_bomb
                IF ( plr6_bomb < 1 )
                    IF ( CHECK_SCORE_GREATER ( player6 , 999 ) )
                       ADD_SCORE ( player6, -1000 )
                    ENDIF
                    IF ( prev_it = 1 )
                        ADD_SCORE ( player1, 2000 )
                    ENDIF
                    IF ( prev_it = 2 )
                        ADD_SCORE ( player2, 2000 )
                    ENDIF
                    IF ( prev_it = 3 )
                        ADD_SCORE ( player3, 2000 )
                    ENDIF
                    IF ( prev_it = 4 )
                        ADD_SCORE ( player4, 2000 )
                    ENDIF
                    IF ( prev_it = 5 )
                        ADD_SCORE ( player5, 2000 )
                    ENDIF
                    EXPLODE_LARGE ( player6 )
                    SET plr_it = 0
                ENDIF
            ENDIF
        ENDIF
    ENDIF

ENDWHILE
 
LEVELEND
